剑网3为什么我的少林7400的装分DPS才3.2W
命中低了，93的木桩以及BOSS都是110%的命中才能100%命中，命中不够自然会导致输出下坡。
其次会心会效太低，会效保证在245%左右最佳，高了就溢出。会心至少在40%。其次你的秘籍和输出方式是否太单调了？建议百度下 多玩剑网三论坛，然后在BBS中找到盒子宏的专栏，里面有个和尚宏，点开进去，里面会有详细的宏以及配装的搭配方式和秘籍的激活方式。
看到一个DPS8W的大师，装备属性是：会心43，会效230，命中107，破防1900.你参考下。
附大师输出宏：
#name 易经宏
#tip 大师输出宏~
#icon 4930
#delay 1
#varbox name:v_syyz,type:bool,tip:特效腰坠,tip_1:使用腰坠,tip_2:不使用腰坠,icon:2842
#varbox name:v_dd,type:num_2,tip:打断模式,tip_1:打断,tip_2:不打断,icon:1511,icon_2:1817
#varbox name:v_bwz,type:num_2,tip:天鼓雷音五阵,tip_1:不保五阵,tip_2:保五阵,icon:1817,icon_2:1680
#varbox name:v_fy,type:num_2,tip:扶摇模式,tip_1:不自动补扶摇,tip_2:自动补扶摇,icon:1817,icon_2:1485
#skillbox 无相诀,擒龙诀,亦枯亦荣
--推荐奇穴：[大明][妙法][身意][幻身][降魔渡厄][金刚怒目][三生][明法][心棍][众嗔]
--自动补般若
/skill [nobuff:般若诀,nobuff:1919]般若诀
--扶摇直上自动开
/skill [fight,v_fy=2]扶摇直上
--危险状态下，开无相
/skill [life<0.4,fight,nobuff:渊&镇山河&春泥护花&圣手织天&蝶戏水&天地低昂&舍身]无相诀
/if [v_hc=1]
/skill [map:英雄战宝军械库|战宝军械库,target:卓力格图,nobuff:镇山河,tprepare:掷锤>0.5] 后撤
/skill [map:英雄大明宫|大明宫,target:何莘涯,nobuff:镇山河,tprepare:力拔千钧>0.7] 后撤
/skill [map:英雄大明宫|大明宫,target:何莘涯,nobuff:镇山河,tprepare:吞云吐纳>0.7] 后撤
/end
/return [!tar]
--佛心好了就开
/skill [fight,nobuff:九襄地玄五阵&金刚伏魔五阵&引羌笛&极乐]佛心诀
--有CWBUFF，众嗔buff快断了，补众嗔（优先级第一）
/skill [buff:1919,cdtime:守缺式<0.2,sklv:6596=1,(bufftime:众嗔;3)<2]守缺式
/if [v_cw=1]
--有CWBUFF，无限韦陀
/skill [buff:1919]韦陀献杵
/elseif [v_cw=2]
--有CWBUFF，交替韦陀拿云
/skill [buff:1919,nav=3]拿云式
/skill [buff:1919]韦陀献杵
/end
--需要打断的情况下先抢珠后捕风
/skill [v_dd=1,tprepare,sktest:抢珠式] 抢珠式
--点了5911（[缘断]）奇穴的时候，才释放捕风式打断
/skill [v_dd=1,tprepare,sklv:5911=1] 捕风式
--开怪首先金刚怒目消耗掉豆，然后守缺式
/skill [nobuff:1919,nobuff:守缺,sktest:守缺式,cdtime:守缺式<0.2,nav=3,cdtime:金刚怒目<0.2]金刚怒目
/skill [nobuff:守缺,cdtime:守缺式<0.2] 守缺式
--记录禅那，之所以记录禅那，是因为放了技能之后，下一个技能就已经准备好释放了，那时候判断禅那会有一定延迟
/var [nav] v_nav
--↓*********无GCD技能部分***********↓
--无相诀之后不开爆发
/if [!expcast:无相诀]
--优先金刚怒目，后擒龙诀
/skill [v_nav=3,fight,tlife<1,sktest:守缺式,cdtime:金刚怒目<0.2,nobuff:1919]金刚怒目
/var [sklv:金刚怒目>0,explast:金刚怒目,0;v_nav]v_nav--释放金刚怒目之后，禅那归零
--GCD在读到接近一半的时候，再开擒龙诀，此后，每次刷到一半就会回一个豆，判定可以很精确
--请勿随意调整GCD的判定数据，否则会造成预判不准在非三豆的情况下打韦陀、拿云
/if [!banskill:擒龙诀,cd0<0.8,cd0>0.6,fight,sktest:守缺式,cdtime:擒龙诀<0.2]
/skill [v_nav=1,fight,cdtime:亦枯亦荣<0.2,nowtime-(v_wtxc;0)<1.5] 亦枯亦荣,擒龙诀
/skill [v_nav<=1]擒龙诀
/end
/var [explast:擒龙诀,3;v_nav]v_nav--释放擒龙诀之后，禅那变成3
--擒龙诀之后，如果金刚怒目好了，优先金刚怒目
/skill [v_nav=3,fight,tlife<1,sktest:守缺式,cdtime:金刚怒目<0.2,nobuff:1919]金刚怒目
/var [sklv:金刚怒目>0,explast:金刚怒目,0;v_nav]v_nav--释放金刚怒目之后，禅那归零
/end
--有捕风式buff，并且可以释放捉影式的时候，释放捉影式
/skill [v_nav<3,buff:捕风式,sktest:捉影式,cdtime:捉影式<0.2] 捉影式
--释放捉影式之后，禅那加一
/var [explast:捉影式,v_nav+1;v_nav]v_nav
--擒龙诀和金刚怒目同时，存在，使用腰坠
/skill [buff:擒龙诀&金刚怒目,v_syyz]腰坠
--缺蓝就不等擒龙诀，直接开亦枯亦荣了
/skill [mana<0.2,v_nav=1,fight,tlife<1,sktest:守缺式,cdtime:亦枯亦荣<0.2]亦枯亦荣
--↓***********有GCD技能部分***********↓
--擒龙诀回豆的判定，如果擒龙诀buff存在的时候，擒龙诀buff的时间接近回豆的时间了，预判回1豆
/var [(bufftime:擒龙诀;18)<17,(bufftime:擒龙诀*10)%15] v_qlj
/if [v_qlj,(v_qlj<0.5),v_nav+1]--时间限制为0-1
/if [!v_added]--时间段内只加一次
/var [v_nav+1] v_nav
/var [true] v_added
/end
/else--时间段外重置加法判定变量
/var [false] v_added
/end
--点了众嗔奇穴的情况下，众嗔快断了的时候，补一个守缺
/skill [cdtime:守缺式<0.2,sklv:6596=1,(bufftime:众嗔;3)<2]守缺式
--阵眼优先守缺
/skill [v_bwz=2,cdtime:守缺式<0.2,buff:天鼓雷音阵,bufftime:天鼓雷音五阵<=1.5]守缺式
--上述技能结束之后，如果禅那预想值大于等于3，优先拿云，之后韦陀。
--守缺回豆无视，因为进入GCD之后宏就重新判定了。
--判断拿云后的一豆
/skill [v_nav>=3,tlife<=0.3,cdtime:拿云式<0.2]拿云式
/if [explast:拿云式,recipe:《龙爪功·拿云式》人偶图残页]
/var [nowtime] v_wtxc
/end
/skill [v_nav>=3,tlife>0.3,cdtime:韦陀献杵<0.2]韦陀献杵
--判断韦陀后的一豆
/if [explast:韦陀献杵,recipe:《罗汉棍法·韦陀献杵》人偶图残页]
/var [nowtime] v_wtxc
/end
--优先守缺，然后横扫，然后普渡,恒河劫沙，然后捕风不用于打断的时候使用捕风
/skill 守缺式
/skill [fight,tar,(sktest:普渡四方;distance<=5;(tar:傀儡·天,dis<=6))] 横扫六合
/skill 普渡四方
/skill 恒河劫沙
/skill [(!sktest:守缺式;cdtime:守缺式>1.2),tar,(sklv:5911~=1;V_dd=2)]捕风式